www.gusucode.com > 深度学习(asp)网址导航 v4.0.1 > 深度学习(asp)网址导航 v4.0.1\code\admin\include\upload_form.asp
<%@LANGUAGE="VBSCRIPT" CODEPAGE="936"%>
<%
session.CodePage=936
response.Charset="gb2312"
Server.ScriptTimeOut=5000
%>
<!--
┌─ 深度学习(asp)上传通用模块 ─────────────────┐
│
│ 版本：ver0.1.2 最后编辑：2009-6-20
│ 作者：吕海鹏
│
└────────────────── www.deepstudy.cn ───┘
-->
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta name="robots" content="noindex,nofollow" />
<meta http-equiv="Content-Type" content="text/html; charset=gb2312" />
<title>深度学习(asp)无组件上传通用模块</title>
<style type="text/css">
body {
font-family:"宋体"; margin:0; padding:0; margin-top:3px;
background: #FFF; font-size:12px; color:#000;
}
input{ margin:1px; border:1px solid #bbb; }
input:focus{ border:1px solid #666; }
.doOK{ color:#00F;}
.doError{ color:#F00;}
</style>
<script language="JavaScript" type="text/javascript">
function check()
{
var oFileName=document.uploadForm.uploadFileName;
if (oFileName.value=="")
{
alert("请选择要上传的文件");
oFileName.focus();
return false;
}
}
</SCRIPT>
</head>
<body>
<%
if(request("action")="add")then
call doSave()
end if
'设置上传文件尺寸 例如：最大为500K 输入 500
MaxSize=request.QueryString("MaxSize")*1024
'设置文件限制格式 允许的附件类型 例如：gif/jpg/rar/zip
FileType=request.QueryString("FileType")
'设置文件的保存路径，
SavePath=request.QueryString("SavePath")
' 返回到表单的值 例如：form1.fProducts_Pic
parentBackValue=request.QueryString("parentBackValue")
'定义上传后的文件名 0：自动取无重复的服务器时间字符串为文件名 '1：自动取源文件名 '字符串：自定义的文件名，如"mypic.jpg"
saveName=request.QueryString("saveName")
if(saveName="")then saveName=0 end if
%>
<form action="?action=add&MaxSize=<%=MaxSize%>&FileType=<%=FileType%>&SavePath=<%=SavePath%>&parentBackValue=<%=parentBackValue%>&saveName=<%=saveName%>" enctype="multipart/form-data" name="uploadForm" method="post" onSubmit="return check()">
图片上传：<input name="uploadFileName" type="file" id="uploadFileName" />
<input type="submit" name="Submit" value="上传" />
(大小<<%=MaxSize/1024%>K 文件类型：<%=FileType%>)
<br />
<br />
<br />
<input type="text" name="MaxSize" value="<%=MaxSize%>"/>
<input type="text" name="FileType" value="<%=FileType%>"/>
<input type="text" name="SavePath" value="<%=SavePath%>"/>
<input type="text" name="parentBackValue" value="<%=parentBackValue%>"/>
<input type="text" name="saveName" value="<%=saveName%>"/>
</form>
</body>
</html>
<%
'===================================
sub doSave()
dim request2 , saveName
'建立上传对象
set request2=New UpLoadClass
'设置为手动保存模式
request2.AutoSave=2
'设置字符集，默认为 gb2312 字符集
'request2.Charset="UTF-8"
request2.Open()
'设置服务器文件保存路径
'request2.SavePath="uploadFiles/"
request2.SavePath=request2.Form("SavePath")
'设置产品大图最大为500K
'当然这里还可以设置不同的保存路径，限制格式
'request2.MaxSize=500*1024
request2.MaxSize=request2.Form("MaxSize")
'设置文件允许的附件类型 例如：gif/jpg/rar/zip
'request2.FileType="gif/jpg/png/bmp"
request2.FileType=request2.Form("FileType")
'如果保存图成功
'Response.Write("")
'Function Save(Item,Name)
'保存表单中 file 域上传的文件，成功保存返回 true，否则返回 false
'Item 是 file 域名称，Name 是保存的文件名
'Name 特征值有：
'0：自动取无重复的服务器时间字符串为文件名
'1：自动取源文件名
'字符串：自定义的文件名，如"mypic.jpg"
saveName=request2.Form("saveName")
'if( isNumeric(saveName) )then int(saveName) end if
select case saveName
case "0"
saveName=0
case "1"
saveName=1
end select
if request2.Save("uploadFileName", saveName ) then
'显示保存位置
Response.Write("上传成功,文件地址：<span class='doOK'>"&request2.SavePath&request2.Form("uploadFileName") & "</span>")
else
response.Write("<span class='doError'>文件上传不成功！！ </span>[<a href='javascript:history.go(-1)'>重新上传</a>]")
end if
'-------说明开始------
'如果是正确的jpg/gig/png/bmp图片格式文件，还可以获取图片宽高
'if request2.form("uploadFileName_Width")<>"" then
'Response.Write("图片宽："&request2.form("uploadFileName_Width"))
'Response.Write("图片高："&request2.form("uploadFileName_Height"))
'end if
'-------说明结束------
'Response.Write "<p>[<a href=""javascript:history.back();"">返回</a>]</p>"
Response.Write ("<script language='JavaScript' type='text/javascript'>")
'Response.Write ("parent.document.form1.fProducts_Pic.value='"&request2.Form("uploadFileName")&"'")
Response.Write ("if(parent.document."&request2.Form("parentBackValue") & ".value==''){")
Response.Write ("parent.document."&request2.Form("parentBackValue") & ".value='" &request2.Form("uploadFileName") & "'" )
Response.Write ("}else{")
Response.Write ("parent.document."&request2.Form("parentBackValue") & ".value+='|" &request2.Form("uploadFileName") & "'" )
Response.Write ("}</script>")
'释放上传对象
set request2=nothing
end sub
'尊重开发者劳动 在此致谢 吕海鹏 www.ITstudy.cn
'----------------------------------------------------------
'**************** 风声无组件上传类 2.11 *****************
'作者：风声
'网站：http://www.fonshen.com
'邮件：webmaster@fonshen.com
'版权：版权全体,源代码公开,各种用途均可免费使用
'**********************************************************
'----------------------------------------------------------
Class UpLoadClass
Private m_TotalSize,m_MaxSize,m_FileType,m_SavePath,m_AutoSave,m_Error,m_Charset
Private m_dicForm,m_binForm,m_binItem,m_strDate,m_lngTime
Public FormItem,FileItem
Public Property Get Version
Version="Fonshen UpLoadClass Version 2.11"
End Property
Public Property Get Error
Error=m_Error
End Property
Public Property Get Charset
Charset=m_Charset
End Property
Public Property Let Charset(strCharset)
m_Charset=strCharset
End Property
Public Property Get TotalSize
TotalSize=m_TotalSize
End Property
Public Property Let TotalSize(lngSize)
if isNumeric(lngSize) then m_TotalSize=Clng(lngSize)
End Property
Public Property Get MaxSize
MaxSize=m_MaxSize
End Property
Public Property Let MaxSize(lngSize)
if isNumeric(lngSize) then m_MaxSize=Clng(lngSize)
End Property
Public Property Get FileType
FileType=m_FileType
End Property
Public Property Let FileType(strType)
m_FileType=strType
End Property
Public Property Get SavePath
SavePath=m_SavePath
End Property
Public Property Let SavePath(strPath)
m_SavePath=Replace(strPath,chr(0),"")
End Property
Public Property Get AutoSave
AutoSave=m_AutoSave
End Property
Public Property Let AutoSave(byVal Flag)
select case Flag
case 0,1,2: m_AutoSave=Flag
end select
End Property
Private Sub Class_Initialize
m_Error = -1
m_Charset = "gb2312"
m_TotalSize= 0
m_MaxSize = 153600
m_FileType = "jpg/gif"
m_SavePath = ""
m_AutoSave = 0
Dim dtmNow : dtmNow = Date()
m_strDate = Year(dtmNow)&Right("0"&Month(dtmNow),2)&Right("0"&Day(dtmNow),2)
m_lngTime = Clng(Timer()*1000)
Set m_binForm = Server.CreateObject("ADODB.Stream")
Set m_binItem = Server.CreateObject("ADODB.Stream")
Set m_dicForm = Server.CreateObject("Scripting.Dictionary")
m_dicForm.CompareMode = 1
End Sub
Private Sub Class_Terminate
m_dicForm.RemoveAll
Set m_dicForm = nothing
Set m_binItem = nothing
m_binForm.Close()
Set m_binForm = nothing
End Sub
Public Function Open()
Open = 0
if m_Error=-1 then
m_Error=0
else
Exit Function
end if
Dim lngRequestSize : lngRequestSize=Request.TotalBytes
if m_TotalSize>0 and lngRequestSize>m_TotalSize then
m_Error=5
Exit Function
elseif lngRequestSize<1 then
m_Error=4
Exit Function
end if
Dim lngChunkByte : lngChunkByte = 102400
Dim lngReadSize : lngReadSize = 0
m_binForm.Type = 1
m_binForm.Open()
do
m_binForm.Write Request.BinaryRead(lngChunkByte)
lngReadSize=lngReadSize+lngChunkByte
if lngReadSize >= lngRequestSize then exit do
loop
m_binForm.Position=0
Dim binRequestData : binRequestData=m_binForm.Read()
Dim bCrLf,strSeparator,intSeparator
bCrLf=ChrB(13)&ChrB(10)
intSeparator=InstrB(1,binRequestData,bCrLf)-1
strSeparator=LeftB(binRequestData,intSeparator)
Dim strItem,strInam,strFtyp,strPuri,strFnam,strFext,lngFsiz
Const strSplit="'"">"
Dim strFormItem,strFileItem,intTemp,strTemp
Dim p_start : p_start=intSeparator+2
Dim p_end
Do
p_end = InStrB(p_start,binRequestData,bCrLf&bCrLf)-1
m_binItem.Type=1
m_binItem.Open()
m_binForm.Position=p_start
m_binForm.CopyTo m_binItem,p_end-p_start
m_binItem.Position=0
m_binItem.Type=2
m_binItem.Charset=m_Charset
strItem = m_binItem.ReadText()
m_binItem.Close()
intTemp=Instr(39,strItem,"""")
strInam=Mid(strItem,39,intTemp-39)
p_start = p_end + 4
p_end = InStrB(p_start,binRequestData,strSeparator)-1
m_binItem.Type=1
m_binItem.Open()
m_binForm.Position=p_start
lngFsiz=p_end-p_start-2
m_binForm.CopyTo m_binItem,lngFsiz
if Instr(intTemp,strItem,"filename=""")<>0 then
if not m_dicForm.Exists(strInam&"_From") then
strFileItem=strFileItem&strSplit&strInam
if m_binItem.Size<>0 then
intTemp=intTemp+13
strFtyp=Mid(strItem,Instr(intTemp,strItem,"Content-Type: ")+14)
strPuri=Mid(strItem,intTemp,Instr(intTemp,strItem,"""")-intTemp)
intTemp=InstrRev(strPuri,"\")
strFnam=Mid(strPuri,intTemp+1)
m_dicForm.Add strInam&"_Type",strFtyp
m_dicForm.Add strInam&"_Name",strFnam
m_dicForm.Add strInam&"_Path",Left(strPuri,intTemp)
m_dicForm.Add strInam&"_Size",lngFsiz
if Instr(strFnam,".")<>0 then
strFext=Mid(strFnam,InstrRev(strFnam,".")+1)
else
strFext=""
end if
select case strFtyp
case "image/jpeg","image/pjpeg","image/jpg"
if Lcase(strFext)<>"jpg" then strFext="jpg"
m_binItem.Position=3
do while not m_binItem.EOS
do
intTemp = Ascb(m_binItem.Read(1))
loop while intTemp = 255 and not m_binItem.EOS
if intTemp < 192 or intTemp > 195 then
m_binItem.read(Bin2Val(m_binItem.Read(2))-2)
else
Exit do
end if
do
intTemp = Ascb(m_binItem.Read(1))
loop while intTemp < 255 and not m_binItem.EOS
loop
m_binItem.Read(3)
m_dicForm.Add strInam&"_Height",Bin2Val(m_binItem.Read(2))
m_dicForm.Add strInam&"_Width",Bin2Val(m_binItem.Read(2))
case "image/gif"
if Lcase(strFext)<>"gif" then strFext="gif"
m_binItem.Position=6
m_dicForm.Add strInam&"_Width",BinVal2(m_binItem.Read(2))
m_dicForm.Add strInam&"_Height",BinVal2(m_binItem.Read(2))
case "image/png"
if Lcase(strFext)<>"png" then strFext="png"
m_binItem.Position=18
m_dicForm.Add strInam&"_Width",Bin2Val(m_binItem.Read(2))
m_binItem.Read(2)
m_dicForm.Add strInam&"_Height",Bin2Val(m_binItem.Read(2))
case "image/bmp"
if Lcase(strFext)<>"bmp" then strFext="bmp"
m_binItem.Position=18
m_dicForm.Add strInam&"_Width",BinVal2(m_binItem.Read(4))
m_dicForm.Add strInam&"_Height",BinVal2(m_binItem.Read(4))
case "application/x-shockwave-flash"
if Lcase(strFext)<>"swf" then strFext="swf"
m_binItem.Position=0
if Ascb(m_binItem.Read(1))=70 then
m_binItem.Position=8
strTemp = Num2Str(Ascb(m_binItem.Read(1)), 2 ,8)
intTemp = Str2Num(Left(strTemp, 5), 2)
strTemp = Mid(strTemp, 6)
while (Len(strTemp) < intTemp * 4)
strTemp = strTemp & Num2Str(Ascb(m_binItem.Read(1)), 2 ,8)
wend
m_dicForm.Add strInam&"_Width", Int(Abs(Str2Num(Mid(strTemp, intTemp + 1, intTemp), 2) - Str2Num(Mid(strTemp, 1, intTemp), 2)) / 20)
m_dicForm.Add strInam&"_Height",Int(Abs(Str2Num(Mid(strTemp, 3 * intTemp + 1, intTemp), 2) - Str2Num(Mid(strTemp, 2 * intTemp + 1, intTemp), 2)) / 20)
end if
end select
m_dicForm.Add strInam&"_Ext",strFext
m_dicForm.Add strInam&"_From",p_start
if m_AutoSave<>2 then
intTemp=GetFerr(lngFsiz,strFext)
m_dicForm.Add strInam&"_Err",intTemp
if intTemp=0 then
if m_AutoSave=0 then
strFnam=GetTimeStr()
if strFext<>"" then strFnam=strFnam&"."&strFext
end if
m_binItem.SaveToFile Server.MapPath(m_SavePath&strFnam),2
m_dicForm.Add strInam,strFnam
end if
end if
else
m_dicForm.Add strInam&"_Err",-1
end if
end if
else
m_binItem.Position=0
m_binItem.Type=2
m_binItem.Charset=m_Charset
strTemp=m_binItem.ReadText
if m_dicForm.Exists(strInam) then
m_dicForm(strInam) = m_dicForm(strInam)&","&strTemp
else
strFormItem=strFormItem&strSplit&strInam
m_dicForm.Add strInam,strTemp
end if
end if
m_binItem.Close()
p_start = p_end+intSeparator+2
loop Until p_start+3>lngRequestSize
FormItem=Split(strFormItem,strSplit)
FileItem=Split(strFileItem,strSplit)
Open = lngRequestSize
End Function
Private Function GetTimeStr()
m_lngTime=m_lngTime+1
GetTimeStr=m_strDate&Right("00000000"&m_lngTime,8)
End Function
Private Function GetFerr(lngFsiz,strFext)
dim intFerr
intFerr=0
if lngFsiz>m_MaxSize and m_MaxSize>0 then
if m_Error=0 or m_Error=2 then m_Error=m_Error+1
intFerr=intFerr+1
end if
if Instr(1,LCase("/"&m_FileType&"/"),LCase("/"&strFext&"/"))=0 and m_FileType<>"" then
if m_Error<2 then m_Error=m_Error+2
intFerr=intFerr+2
end if
GetFerr=intFerr
End Function
Public Function Save(Item,strFnam)
Save=false
if m_dicForm.Exists(Item&"_From") then
dim intFerr,strFext
strFext=m_dicForm(Item&"_Ext")
intFerr=GetFerr(m_dicForm(Item&"_Size"),strFext)
if m_dicForm.Exists(Item&"_Err") then
if intFerr=0 then
m_dicForm(Item&"_Err")=0
end if
else
m_dicForm.Add Item&"_Err",intFerr
end if
if intFerr<>0 then Exit Function
if VarType(strFnam)=2 then
select case strFnam
case 0:strFnam=GetTimeStr()
if strFext<>"" then strFnam=strFnam&"."&strFext
case 1:strFnam=m_dicForm(Item&"_Name")
end select
end if
m_binItem.Type = 1
m_binItem.Open
m_binForm.Position = m_dicForm(Item&"_From")
m_binForm.CopyTo m_binItem,m_dicForm(Item&"_Size")
m_binItem.SaveToFile Server.MapPath(m_SavePath&strFnam),2
m_binItem.Close()
if m_dicForm.Exists(Item) then
m_dicForm(Item)=strFnam
else
m_dicForm.Add Item,strFnam
end if
Save=true
end if
End Function
Public Function GetData(Item)
GetData=""
if m_dicForm.Exists(Item&"_From") then
if GetFerr(m_dicForm(Item&"_Size"),m_dicForm(Item&"_Ext"))<>0 then Exit Function
m_binForm.Position = m_dicForm(Item&"_From")
GetData = m_binForm.Read(m_dicForm(Item&"_Size"))
end if
End Function
Public Function Form(Item)
if m_dicForm.Exists(Item) then
Form=m_dicForm(Item)
else
Form=""
end if
End Function
Private Function BinVal2(bin)
dim lngValue,i
lngValue = 0
for i = lenb(bin) to 1 step -1
lngValue = lngValue *256 + Ascb(midb(bin,i,1))
next
BinVal2=lngValue
End Function
Private Function Bin2Val(bin)
dim lngValue,i
lngValue = 0
for i = 1 to lenb(bin)
lngValue = lngValue *256 + Ascb(midb(bin,i,1))
next
Bin2Val=lngValue
End Function
Private Function Num2Str(num, base, lens)
Dim ret,i
ret = ""
while(num >= base)
i = num Mod base
ret = i & ret
num = (num - i) / base
wend
Num2Str = Right(String(lens, "0") & num & ret, lens)
End Function
Private Function Str2Num(str, base)
Dim ret, i
ret = 0
for i = 1 to Len(str)
ret = ret * base + Cint(Mid(str, i, 1))
next
Str2Num = ret
End Function
End Class
%>